10 REM SAVE"@0:MENU.BAS",08:REM BY DAVID SCHMOLL
20 IFLF=1THEN390
30 U=PEEK(186):SA=8500:RS=65533:DD=56584:CU=08:REM CU IS DEVICE FOR CLOCK
40 IFPEEK(RS)=255THENPOKE981,15:SYS40994:POKE216,0:POKE7168,0:S=PEEK(215)
50 IFPEEK(RS)<>255THENPN=PEEK(678):TV=260:REM 64 MODE
60 IFPEEK(RS)=255THENPN=PEEK(2563):TV=200:REM 128 MODE
70 IFPN=0THENPOKEDD+6,(PEEK(DD+6)AND127):REM NTSC
80 IFPN=255THENPOKEDD+6,(PEEK(DD+6)OR128):REM PAL
90 POKE53280,0:POKE53281,0:IFSTHENTV=230:SYS30643
110 OPEN15,CU,15:CLOSE15:IFPEEK(144)=0THEN140
120 CU=CU+1:IFCU>=31THEN220
130 GOTO110
140 OPEN15,CU,15,"T-RB":REM CMD RTC CODE
150 FORX=0TO8
160 GET#15,A$(X):IF A$(X)=""THEN A$(X)=CHR$(0)
170 NEXTX
180 IF(A$(0)<>"3")AND(ST=64)THENPOKESA-1,(0ORASC(A$(2))):CLOSE15:GOTO320
190 POKESA-1,(128ORASC(A$(2)))
200 GET#15,E$:IFST=0THEN200
210 CLOSE15:GOTO120
220 TI$="000000":PRINTCHR$(147);CHR$(14);"SET CLOCK Y/[206] ? "
230 P$=CHR$(19):FORX=1TO15:P$=P$+CHR$(29):NEXTX
240 FORX=0TOTV
250 GETT$:ON-(T$="Y")-(T$<>"")GOTO 380,270:PRINT P$;STR$(9-INT(TI/60))
260 NEXT:GOTO380
270 PRINTCHR$(17):INPUT"ENTER TIME (HHMMSSX)";T$
280 Y=4:FORX=1TO5STEP2
290 A$(Y)=CHR$(16*VAL(MID$(T$,X,1))+VAL(MID$(T$,X+1,1))):Y=Y+1
300 NEXTX:POKESA-1,(0ORASC(A$(2)))
310 A$(Y)=CHR$(128):IFMID$(T$,X,1)="A"THENA$(X)=CHR$(0)
320 IFA$(7)<>CHR$(0)THENA$(4)=CHR$(ASC(A$(4))+128)
330 H=ASC(A$(4)):IF(HAND127)=18THENA$(4)=CHR$(H-(SGN(H-128)*128))
340 POKEDD+7,(PEEK(DD+7)AND127)
350 FORX=4TO7:POKEDD+7-X,ASC(A$(X)):NEXT
360 REM EZ LOADER USES CIA#2 REGISTERS FOR TOD CLOCK
380 LF=1:LOAD"MENU.ML",U,1
390 SYSSA